Formal grammar (EBNF)

program     = { statement } ;

statement   = module
            | context
            | drink
            | glass
            | pour
            | return
            | policy
            | exprStmt ;

module      = "module" IDENT ":" ( "core" | "governed" ) [ ";" ] ;
context     = "context" "{" { field } "}" ;
field       = IDENT ":" expr [ "," ] ;
drink       = "drink" IDENT [ ":" IDENT ] "=" expr [ ";" ] ;
glass       = "glass" IDENT "(" [ params ] ")"
              [ "requires" expr ] [ "ensures" expr ] block ;
params      = IDENT [ ":" IDENT ] { "," IDENT [ ":" IDENT ] } ;
pour        = "pour" expr [ ";" ] ;
return      = "return" expr [ ";" ] ;
policy      = "policy" IDENT { context | rule } ;
context     = "context" "{" { field } "}" ;
rule        = "when" expr "=>" ( "ALLOW" | "DENY" | "ESCALATE" ) [ ";" ] ;
block       = "{" { statement } "}" ;
exprStmt    = expr [ ";" ] ;

expr        = orExpr ;
orExpr      = andExpr  { ( "or"  | "||" ) andExpr } ;
andExpr     = eqExpr   { ( "and" | "&&" ) eqExpr } ;
eqExpr      = cmpExpr  { ( "==" | "!=" ) cmpExpr } ;
cmpExpr     = addExpr  { ( "<" | ">" | "<=" | ">=" | "in" ) addExpr } ;
addExpr     = mulExpr  { ( "+" | "-" ) mulExpr } ;
mulExpr     = unary    { ( "*" | "/" | "%" ) unary } ;
unary       = ( "not" | "!" | "-" ) unary | postfix ;
postfix     = primary { "." IDENT } ;
primary     = NUMBER | STRING | "true" | "false" | "null"
            | list | object | call | IDENT | "(" expr ")" ;
list        = "[" [ expr { "," expr } ] "]" ;
object      = "{" [ field { field } ] "}" ;
call        = IDENT "(" [ expr { "," expr } ] ")" ;

(* Lexical *)
IDENT       = LETTER { LETTER | DIGIT | "_" } ;
NUMBER      = DIGIT { DIGIT | "_" } [ "." DIGIT { DIGIT } ] ;
STRING      = '"' { CHAR } '"' | "'" { CHAR } "'" ;
COMMENT     = ( "//" | "#" ) { CHAR } NEWLINE ;